Excel : conversion d'une durée en journées de 8 heures

[difqonapple]

Bonjour, je pose ma question car peut être que certains d'entre vous sont extrêmement doué en excel
A la base, c'est assez simple, j'essaye de planifier la durée d'une tache. Jusque là ça va.
Pour cela, je calcul en fonction d'une formule le tps en heures nécessaire. Là ou ça se complique, c'est que quand je transforme ce nombre d'heure en jours/heures grâce au format ce cellule, ça me compte une journée = 24H... alors qu'une journée de travail = 8H...
Pour résoudre cela, j'ai appliqué la formule suivante:

=SI(I29/24>=1/3;I29/8;I29/24)

ce qui est déjà pas si mal mais rend des erreurs... en effet, 79,4Heure = 9j 22H d'après la formules... alors que j'aimerais qu'elle me rende 9J & 7H (+ qq minutes...)

j'ai trouvé ceci sur internet:

=SI(ENT(B1/8);ENT(B1/8)&" J";"")&SI(MOD(B1;8);" "&MOD(B1;8)&" H";"")

Ca a l'air pas mal, mis à par que je n'ai plus que des jours ou des heures, là ou j'aimerais avoir des Jours & des heures à chaque fois...(meme si 0 jours)
Comment puis-je demander à cette formule qu'elle me rende des des jours & heures à chaque fois... je n'ai pas réussi à a la modifier dans ce but la...
Si qqn à la solution... vous serez mon sauveur !

 

[osnola]

Bonjour,

j'ai trouvé ceci sur internet:
...
Comment puis-je demander à cette formule qu'elle me rende des des jours & heures à chaque fois... je n'ai pas réussi à a la modifier dans ce but la...

as-tu essayé :

=ENT(B1/8)&" J "&MOD(B1;8)&" H"

ie. de remplacer les SI(cond, siVrai, siFaux) par siVrai puisque tu veux toujours afficher ces valeurs ...

 

[Aliboron]

Toutafé. Je pousserais même le soin du détail jusqu'à l'écrire :

=ENT(B1/8)&" j "& ARRONDI(MOD(B1;8);2) &" h"

Pour éviter l'aspect disgracieux des décimales à rallonge.

 

[difqonapple]

Merci beaucoup...!!!!!! ce n'était pas si dur en fait... mais excel il faut en faire bcp pour avoir vrmt les réflexes... et je n'en fais plus beaucoup malheureusement :/

Juste une question, pour ma culture, serait-il possible de demander d'afficher les minutes ?
Prenons un exemple:
J'obtiens 8,17H, avec la formules, ça me donne 1J0,17h... mais combien font ces 0,17h(=10minutes)... ? En gros, comment obtenir 1J 0H 10M? Ce n'est peut être pas possible mais si savez sans trop de recherche, ça m'intéresse

Merci pour votre aide !
ps: J'ai modifié un peu la formule avec arrondi.sup pour qu'une tache dispose toujours d'une heure complète pour être effectuée, une fois l'heure entamée.
Ca donne:

=ENT(I7/8)&" j "&ARRONDI.SUP(MOD(I7;8);1)&" h"

Encore merci !

 

[osnola]

....
J'obtiens 8,17H, avec la formules, ça me donne 1J0,17h... mais combien font ces 0,17h(=10minutes)... ? En gros, comment obtenir 1J 0H 10M? Ce n'est peut être pas possible mais si savez sans trop de recherche, ça m'intéresse
...

Oui, c'est possible en tapant :

=ENT(I7/8)&" j "&ENT(MOD(I7;8))&" h "&ARRONDI.SUP(MOD(I7;1)*60;1)&" m"

ie. MOD(17;1) doit renvoyer la partie décimale de I7(*) ; en multipliant par 60, tu obtiens le nombre de minutes que tu peux arrondir ensuite.

(*) il n'est pas impossible qu'il existe une fonction qui donne directement la partie décimale, à vérifier

 

[difqonapple]

Okay, merci, j'ai compris "l'astuce"
Thank's

 

[Aliboron]

(*) il n'est pas impossible qu'il existe une fonction qui donne directement la partie décimale,

En effet, sous réserve que la partie fractionnaire soit bien décimale (c'est à dire que lorsqu'on lit 8,17 h il ne s'agisse pas de 8 h et 17 min mais bien de 8 h et 17 centièmes d'heures, alors on peut avoir cela simplement :

=ENT(I7/8)&" j "&HEURE(MOD(I7;8)/24)&" h "&MINUTE(MOD(I7;8)/24) & " min"

En réalité, la seule subtilité dans l'affaire, c'est la division par 8 pour obtenir le nombre de journées (le terme journée convient mieux que jours, dans le cas présent). Pour le reste, on est dans un schéma plus classique, où la valeur 1 vaut un jour, donc 24 heures, 1440 minutes, etc. (d'où la nécessité de diviser par 24 le résultat des calculs).