Logiciel d'automation audio

[FromHere]

Bonjour,

je recherche une application toute simple (et si possible gratuite) pour effectuer une automation/programmation simple. Je voudrais faire les choses suivantes :

1) écouter de la musique aléatoire à partir d'une playlist "playlist1" (playlist Itunes ou autre)
2) Insérer 1 jingle aléatoire à partir d'une playlist "jingle" toutes les 3, 4 ou 5 chansons (à définir) de la playlist1
3) Et, si possible, diffuser un spot/annonce à partir d'une playlist "annonce" à des moments précis (toutes les heures fixes ou à un moment défini)

J'ai trouvé des applis comme "Radiologik" , "RadioRack" ou "Megaseg" mais tout cela me semble bien compliqué et fort usine à gaz pour ce que je désire faire.

Merci pour vos idées et suggestions

 

[JacqR]

Vous pouvez faire cela avec un script dans une application de type "Cocoa-AppleScript Applet"

Ouvrir l'application "Éditeur de script":

Sélectionnez le menu "Cocoa-AppleScript Applet" dans le menu "Nouveau à partir d'un modèle" du menu "Fichier"
Sélectionnez le menu "Afficher le contenu du paquet" dans le menu "Présentation"
Faites un double-clic sur l'icône "CocoaAppletAppDelegate.scpt"
Supprimer tout le texte dans la fenêtre.

Copié/collé ce script AppleScript :

--  CocoaAppletAppDelegate.applescript
--  Cocoa-AppleScript Applet

script CocoaAppletAppDelegate
    property firstList : "playlist1" -- écouter de la musique à partir de cette liste de lecture
    property secList : "jingle" --  jingle aléatoire à partir de cette liste de lecture
    property myInterval : 4 -- joue 4  chansons  dans firstList avant de jouer un jingle
    property tCounter : 0
    property isPaused : false
    property parent : class "NSObject"
 
    on applicationWillFinishLaunching:aNotification
        tell application "iTunes" to play some track of playlist firstList
        current application's NSDistributedNotificationCenter's defaultCenter()'s addObserver:me selector:"updateCounter:" |name|:"com.apple.iTunes.playerInfo" object:(missing value)
    end applicationWillFinishLaunching:
 
    on applicationShouldTerminate:sender
        current application's NSDistributedNotificationCenter's defaultCenter()'s removeObserver:me
        return current application's NSTerminateNow
    end applicationShouldTerminate:
 
    on updateCounter:aNotification
        set aDict to aNotification's userInfo
        if (|Player State| of aDict) as text is "Playing" then
            if not isPaused then
                set tCounter to tCounter + 1
                if tCounter > myInterval then
                    set tCounter to -3 -- le compteur monte de un quand on joue le jingle et de un quand le jingle se terminera, donc le compteur sera  à -1 quand le jingle se terminera
                    tell application "iTunes" to play some track of playlist secList
                else if tCounter = -1 then -- le jingle est terminé
                    -- le compteur monte de un quand on lance une musique par code et de un quand la musique se terminera, donc le compteur sera  à 1 quand la musique  se terminera
                    tell application "iTunes" to play some track of playlist firstList
                end if
            else -- l'utilisateur remets la lecture dans iTunes
                set isPaused to false
            end if
        else if (|Player State| of aDict) as text is "Paused" then -- pause iTunes par l'utilisateur
            set isPaused to true
        end if
    end updateCounter:
end script

Il suffit de modifier les lignes 5, 6 et 7 dans le script selon vos choix
Compiler, enregistrer le script et quitter l'éditeur.
Lancer l'application pour jouer de la musique dans iTunes.​

Plus tard, si vous faire des modifications dans le script de l'application :

Premièrement, fermer l'application si ouverte.
Glissé/déposé l'application sur l'icône de l'application "Éditeur de script"
Faites vos modifications dans le script, compiler, enregistrer et quitter.​

 

[FromHere]

Vous pouvez faire cela avec un script dans une application de type "Cocoa-AppleScript Applet"

Ouvrir l'application "Éditeur de script":

Sélectionnez le menu "Cocoa-AppleScript Applet" dans le menu "Nouveau à partir d'un modèle" du menu "Fichier"
Sélectionnez le menu "Afficher le contenu du paquet" dans le menu "Présentation"
Faites un double-clic sur l'icône "CocoaAppletAppDelegate.scpt"
Supprimer tout le texte dans la fenêtre.

Copié/collé ce script AppleScript :

--  CocoaAppletAppDelegate.applescript
--  Cocoa-AppleScript Applet

script CocoaAppletAppDelegate
    property firstList : "playlist1" -- écouter de la musique à partir de cette liste de lecture
    property secList : "jingle" --  jingle aléatoire à partir de cette liste de lecture
    property myInterval : 4 -- joue 4  chansons  dans firstList avant de jouer un jingle
    property tCounter : 0
    property isPaused : false
    property parent : class "NSObject"

    on applicationWillFinishLaunching:aNotification
        tell application "iTunes" to play some track of playlist firstList
        current application's NSDistributedNotificationCenter's defaultCenter()'s addObserver:me selector:"updateCounter:" |name|:"com.apple.iTunes.playerInfo" object:(missing value)
    end applicationWillFinishLaunching:

    on applicationShouldTerminate:sender
        current application's NSDistributedNotificationCenter's defaultCenter()'s removeObserver:me
        return current application's NSTerminateNow
    end applicationShouldTerminate:

    on updateCounter:aNotification
        set aDict to aNotification's userInfo
        if (|Player State| of aDict) as text is "Playing" then
            if not isPaused then
                set tCounter to tCounter + 1
                if tCounter > myInterval then
                    set tCounter to -3 -- le compteur monte de un quand on joue le jingle et de un quand le jingle se terminera, donc le compteur sera  à -1 quand le jingle se terminera
                    tell application "iTunes" to play some track of playlist secList
                else if tCounter = -1 then -- le jingle est terminé
                    -- le compteur monte de un quand on lance une musique par code et de un quand la musique se terminera, donc le compteur sera  à 1 quand la musique  se terminera
                    tell application "iTunes" to play some track of playlist firstList
                end if
            else -- l'utilisateur remets la lecture dans iTunes
                set isPaused to false
            end if
        else if (|Player State| of aDict) as text is "Paused" then -- pause iTunes par l'utilisateur
            set isPaused to true
        end if
    end updateCounter:
end script

Il suffit de modifier les lignes 5, 6 et 7 dans le script selon vos choix
Compiler, enregistrer le script et quitter l'éditeur.
Lancer l'application pour jouer de la musique dans iTunes.​

Plus tard, si vous faire des modifications dans le script de l'application :

Premièrement, fermer l'application si ouverte.
Glissé/déposé l'application sur l'icône de l'application "Éditeur de script"
Faites vos modifications dans le script, compiler, enregistrer et quitter.​

Bonjour JacqR,

un tout grand merci pour votre réponse, j'essaie cela dès que possible (suis encore au boulot)