[osX10.6.8] dupliquer et renommer un fichier selon une liste

[ccciolll]

DUPLIQUER DES DOSSIERS ET DÉTERMINER LEUR NOM À PARTIR D'UNE LISTE DE NOMS DANS EXCEL
Pour mémoire, une méthode qui fonctionne

1 ) enregistrer la liste de noms excel au format txt + tab
2 ) créer le dossier modèle de départ qu'on souhaite dupliquer
3 ) créer un dossier de destination pour tout ça.
4 ) aller dans Applications > Utilitaires > Editeur Applescript
5 ) copier le code suivant :

set fichiersource to choose folder with prompt "Sélectionnez le dossier à dupliquer."
set dossiercible to choose folder with prompt "Sélectionnez le dossier où vous voulez dupliquer le modèle."
set laliste to choose file with prompt "séléctionnez le fichier liste"
tell application "Finder" to set l_extension to name extension of fichiersource
if l_extension is not "" then set l_extension to "." & l_extension


open for access laliste
read laliste
set tout_le_fichier to the result
close access laliste
set AppleScript's text item delimiters to (ASCII character 13)
set toutes_les_lignes to (every text item of tout_le_fichier) as list
set AppleScript's text item delimiters to ""
set tout_le_fichier to ""

repeat with une_ligne in toutes_les_lignes
    my duplicateFile(une_ligne, fichiersource, dossiercible, l_extension)
end repeat


on duplicateFile(nom, fichiersource, dossiercible, l_extension)
    tell application "Finder" to try
        set x to duplicate fichiersource to dossiercible
        set name of x to nom & l_extension
    end try
end duplicateFile
tell application "Finder"
    (display dialog ("waouou ... Ca y est c'est fait !") buttons {"Salut !"})
end tell

6 ) cliquer sur compiler (il vérifie que c'est correct)
7) cliquer sur Éxécuter
8 suivre les instructions à l'écran et ça roule.

FAIRE LA MÊME CHOSE AVEC DES FICHIERS PLUTÔT QUE DES DOSSIERS
Tout pareil à un détail près : modifier la 1ere ligne du code par
set fichiersource to choose file with prompt "Sélectionnez le fichier à dupliquer."